Qt 5.6 | Qt Quick | Qt Quick Particles Examples - CustomParticle | fragmentshader.qml Example File

Qt 5.6.2 Reference Documentation

# fragmentshader.qml Example File

particles/customparticle/content/fragmentshader.qml

      /****************************************************************************
      **
      ** Copyright (C) 2015 The Qt Company Ltd.
      ** Contact: http://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** You may use this file under the terms of the BSD license as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.0
      import QtQuick.Particles 2.0

      ParticleSystem {
          id: root
          width: 320
          height: 480
          Rectangle {
              z: -1
              anchors.fill: parent
              color: "black"
              Text {
                  anchors.bottom: parent.bottom
                  anchors.horizontalCenter: parent.horizontalCenter
                  font.pixelSize: 14
                  color: "white"
                  text: "It's all in the fragment shader."
              }
          }

          Emitter {
              emitRate: 400
              lifeSpan: 8000
              size: 24
              sizeVariation: 16
              velocity: PointDirection {x: root.width/10; y: root.height/10;}
              acceleration: PointDirection {x: -root.width/40; y: -root.height/40; xVariation: -root.width/20; yVariation: -root.width/20}
          }

          CustomParticle {
              vertexShader:"
                  uniform lowp float qt_Opacity;
                  varying lowp float fFade;
                  varying highp vec2 fPos;

                  void main() {
                      qt_TexCoord0 = qt_ParticleTex;
                      highp float size = qt_ParticleData.z;
                      highp float endSize = qt_ParticleData.w;

                      highp float t = (qt_Timestamp - qt_ParticleData.x) / qt_ParticleData.y;

                      highp float currentSize = mix(size, endSize, t * t);

                      if (t < 0. || t > 1.)
                      currentSize = 0.;

                      highp vec2 pos = qt_ParticlePos
                      - currentSize / 2. + currentSize * qt_ParticleTex          // adjust size
                      + qt_ParticleVec.xy * t * qt_ParticleData.y         // apply velocity vector..
                      + 0.5 * qt_ParticleVec.zw * pow(t * qt_ParticleData.y, 2.);

                      gl_Position = qt_Matrix * vec4(pos.x, pos.y, 0, 1);

                      highp float fadeIn = min(t * 20., 1.);
                      highp float fadeOut = 1. - max(0., min((t - 0.75) * 4., 1.));

                      fFade = fadeIn * fadeOut * qt_Opacity;
                      fPos = vec2(pos.x/320., pos.y/480.);
                  }
              "
              fragmentShader: "
                  varying highp vec2 fPos;
                  varying lowp float fFade;
                  varying highp vec2 qt_TexCoord0;
                  void main() {//*2 because this generates dark colors mostly
                      highp vec2 circlePos = qt_TexCoord0*2.0 - vec2(1.0,1.0);
                      highp float dist = length(circlePos);
                      highp float circleFactor = max(min(1.0 - dist, 1.0), 0.0);
                      gl_FragColor = vec4(fPos.x*2.0 - fPos.y, fPos.y*2.0 - fPos.x, fPos.x*fPos.y*2.0, 0.0) * circleFactor * fFade;
                  }"

          }
      }