Qt Reference Documentation

# QML Image Element

The Image element displays an image in a declarative user interface More...

Inherits Item

Inherited by AnimatedImage.

This element was introduced in Qt 4.7.

- List of all members, including inherited members

## Properties

- asynchronous : bool
- cache : bool
- fillMode : enumeration
- mirror : bool
- paintedHeight : real
- paintedWidth : real
- progress : real
- smooth : bool
- source : url
- sourceSize : QSize
- status : enumeration

## Detailed Description

The Image element is used to display images in a declarative user interface.

The source of the image is specified as a URL using the source property. Images can be supplied in any of the standard image formats supported by Qt, including bitmap formats such as PNG and JPEG, and vector graphics formats such as SVG. If you need to display animated images, use the AnimatedImage element.

If the width and height properties are not specified, the Image element automatically uses the size of the loaded image. By default, specifying the width and height of the element causes the image to be scaled to that size. This behavior can be changed by setting the fillMode property, allowing the image to be stretched and tiled instead.

## Example Usage

The following example shows the simplest usage of the Image element.

     import QtQuick 1.0

     Image {
         source: "pics/qtlogo.png"
     }

## Performance

By default, locally available images are loaded immediately, and the user interface is blocked until loading is complete. If a large image is to be loaded, it may be preferable to load the image in a low priority thread, by enabling the asynchronous property.

If the image is obtained from a network rather than a local resource, it is automatically loaded asynchronously, and the progress and status properties are updated as appropriate.

Images are cached and shared internally, so if several Image elements have the same source, only one copy of the image will be loaded.

Note: Images are often the greatest user of memory in QML user interfaces. It is recommended that images which do not form part of the user interface have their size bounded via the sourceSize property. This is especially important for content that is loaded from external sources or provided by the user.

See also Image example and QDeclarativeImageProvider.

## Property Documentation

asynchronous : bool

Specifies that images on the local filesystem should be loaded asynchronously in a separate thread. The default value is false, causing the user interface thread to block while the image is loaded. Setting asynchronous to true is useful where maintaining a responsive user interface is more desirable than having images immediately visible.

Note that this property is only valid for images read from the local filesystem. Images loaded via a network resource (e.g. HTTP) are always loaded asynchonously.

cache : bool

Specifies whether the image should be cached. The default value is true. Setting cache to false is useful when dealing with large images, to make sure that they aren't cached at the expense of small 'ui element' images.

This property group was introduced in QtQuick 1.1.

fillMode : enumeration

Set this property to define what happens when the source image has a different size than the item.

- Image.Stretch - the image is scaled to fit
- Image.PreserveAspectFit - the image is scaled uniformly to fit without cropping
- Image.PreserveAspectCrop - the image is scaled uniformly to fill, cropping if necessary
- Image.Tile - the image is duplicated horizontally and vertically
- Image.TileVertically - the image is stretched horizontally and tiled vertically
- Image.TileHorizontally - the image is stretched vertically and tiled horizontally

Stretch (default)

     Image {
         width: 130; height: 100
         smooth: true
         source: "qtlogo.png"
     }

PreserveAspectFit

     Image {
         width: 130; height: 100
         fillMode: Image.PreserveAspectFit
         smooth: true
         source: "qtlogo.png"
     }

PreserveAspectCrop

     Image {
         width: 130; height: 100
         fillMode: Image.PreserveAspectCrop
         smooth: true
         source: "qtlogo.png"
         clip: true
     }

Tile

     Image {
         width: 120; height: 120
         fillMode: Image.Tile
         source: "qtlogo.png"
     }

TileVertically

     Image {
         width: 120; height: 120
         fillMode: Image.TileVertically
         smooth: true
         source: "qtlogo.png"
     }

TileHorizontally

     Image {
         width: 120; height: 120
         fillMode: Image.TileHorizontally
         smooth: true
         source: "qtlogo.png"
     }

Note that `clip` is `false` by default which means that the element might paint outside its bounding rectangle even if the fillMode is set to `PreserveAspectCrop`.

See also Image example.

mirror : bool

This property holds whether the image should be horizontally inverted (effectively displaying a mirrored image).

The default value is false.

This property group was introduced in QtQuick 1.1.

read-only paintedWidth : real
read-only paintedHeight : real

These properties hold the size of the image that is actually painted. In most cases it is the same as `width` and `height`, but when using a `fillMode` `PreserveAspectFit` or `fillMode` `PreserveAspectCrop` `paintedWidth` or `paintedHeight` can be smaller or larger than `width` and `height` of the Image element.

read-only progress : real

This property holds the progress of image loading, from 0.0 (nothing loaded) to 1.0 (finished).

See also status.

smooth : bool

Set this property if you want the image to be smoothly filtered when scaled or transformed. Smooth filtering gives better visual quality, but is slower. If the image is displayed at its natural size, this property has no visual or performance effect.

Note: Generally scaling artifacts are only visible if the image is stationary on the screen. A common pattern when animating an image is to disable smooth filtering at the beginning of the animation and reenable it at the conclusion.

source : url

Image can handle any image format supported by Qt, loaded from any URL scheme supported by Qt.

The URL may be absolute, or relative to the URL of the component.

See also QDeclarativeImageProvider.

sourceSize : QSize

This property holds the actual width and height of the loaded image.

Unlike the width and height properties, which scale the painting of the image, this property sets the actual number of pixels stored for the loaded image so that large images do not use more memory than necessary. For example, this ensures the image in memory is no larger than 1024x1024 pixels, regardless of the Image's width and height values:

     Rectangle {
         width: ...
         height: ...

         Image {
            anchors.fill: parent
            source: "reallyBigImage.jpg"
            sourceSize.width: 1024
            sourceSize.height: 1024
         }
     }

If the image's actual size is larger than the sourceSize, the image is scaled down. If only one dimension of the size is set to greater than 0, the other dimension is set in proportion to preserve the source image's aspect ratio. (The fillMode is independent of this.)

If the source is an instrinsically scalable image (eg. SVG), this property determines the size of the loaded image regardless of intrinsic size. Avoid changing this property dynamically; rendering an SVG is slow compared to an image.

If the source is a non-scalable image (eg. JPEG), the loaded image will be no greater than this property specifies. For some formats (currently only JPEG), the whole image will never actually be loaded into memory.

Since QtQuick 1.1 the sourceSize can be cleared to the natural size of the image by setting sourceSize to `undefined`.

Note: Changing this property dynamically causes the image source to be reloaded, potentially even from the network, if it is not in the disk cache.

read-only status : enumeration

This property holds the status of image loading. It can be one of:

- Image.Null - no image has been set
- Image.Ready - the image has been loaded
- Image.Loading - the image is currently being loaded
- Image.Error - an error occurred while loading the image

Use this status to provide an update or respond to the status change in some way. For example, you could:

- Trigger a state change:

       State { name: 'loaded'; when: image.status == Image.Ready }

- Implement an `onStatusChanged` signal handler:

       Image {
           id: image
           onStatusChanged: if (image.status == Image.Ready) console.log('Loaded')
       }

- Bind to the status value:

       Text { text: image.status == Image.Ready ? 'Loaded' : 'Not loaded' }

See also progress.